很明显的，Windows中的控件提供了比VB中的控件多的多的属性。或者是因为Microsoft太懒了，或者Microsoft认为，一个用VB的程序员，永远不会碰到那些属性。

　　 比方说，我们来看看一个很普通的多行文本框。它和Windows中的编辑框（Edit Box）几乎在功能上几乎没有什么区别，只不过少了几个属性。比如，编辑框中有一个属性用来指明它所包含的文本行数，你还可以通过属性来得到编辑框中看的见的第一行文本的行序号（同下拉列表的TopIndex相类似）。

　　 那么，可以通过什么方法来发掘这些本来不存在于VB中的属性吗？答案是肯定的。只不过有点麻烦，又要用到API了。在一个名为SendMessage的API函数的帮助下，我们对普通的文本框的功能进行一些很有用的扩展：你可以把文本框中的每一行当作一个字符串数组中的一个元素来处理。当你想要对文本框的内容进行分析的时候，这是非常有用的。比方说，如果你想做一个HTML的编辑器程序，并且希望它能有彩色代码来区分不同得代码段（和VB的代码编辑器差不多的），对每一行进行分析要比对整个文本进行分析不是要来的方便，容易的多吗？下面我们来看看例子。

　　 Let's get to work...

　　 既然要用到API函数，首先要做的当然是声明SendMessage了：

Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long

　　 你还有对要发送给文本框的消息进行声明。比方说，如果你想要写一个能告诉你文本框中第一个可见行的序号的函数，你就要作如下的消息声明：

Public Const EM_GETFIRSTVISIBLELINE = &HCE

　　 然后你就可以写函数了：

Public Function TopLineIndex(txtBox As TextBox) As Long
    TopLineIndex = SendMessage(txtBox.hwnd, EM_GETFIRSTVISIBLELINE, 0&, 0&)
End Function

　　 因为消息EM_GETFIRSTVISIBLELINE不需要任何的参数，因而wParam 和lParam都必须赋值为0。如果你想把这个函数应用在一个富文本框上而标准文本框，仅仅需要把函数的的参数类型由TextBox改为RichTextBox就可以了。不过要记得得是，这个行序号是以0为开始的，当函数返回0时指的是第一行。

　　 富文本框有一个方法GetLineFromChar能够更具给定的字符序号来判断它所在的行序号。而标准的文本框却没有这个功能。我们已可以通过上面的方法来解决这个问题。不过这一次，你需要用到的是EM_LINEFROMCHAR消息：

Public Const EM_LINEFROMCHAR = &HC9
EM_LINEFROMCHAR消息把要传递的字符序号放在参数wParam中:

Public Function GetLineFromChar(txtBox As TextBox, CharPos As Long) As Long
    GetLineFromChar = SendMessage( _txtBox.hWnd, EM_LINEFROMCHAR, CharPos, 0&)
End Function

　　 因而，如果你想知道光标所在行的具体的行序号，用上面的这个函数就可以轻松的实现了：

Dim lngLineIndex As Long
lngLineIndex = GetLineFromChar(Text1, Text1.SelStart)
MsgBox "You are on line number " & lngLineIndex + 1

　　 反过来，你也可以查到每一行的第一个字符在全文中的字符序号，EM_LINEINDEX消息能帮助你做到这一点：

Public Const EM_LINEINDEX = &HBB
Public Function GetCharFromLine(txtBox As TextBox, LineIndex As Long) As Long
    GetCharFromLine = SendMessage( _
            txtBox.hwnd, EM_LINEINDEX, LineIndex, 0&)
End Function

　　 想知道文本框里到底有多少行？简单：用EM_GETLINECOUNT消息就可以轻松搞定。同样的，因为这个消息不带任何的参数，我们还是把参数wParam和lParam都置为0：

　　 Public Const EM_GETLINECOUNT = &HBA
　　 Public Function LineCount(txtBox As TextBox) As Long
　　 LineCount = SendMessage( _
　　 TxtBox.hWnd, EM_GETLINECOUNT, 0&, 0&)
　　 End Function

OK，确实很简单吧，我们再来看看另外一个消息：EM_LINELENGTH。通过制定在参数wParam的一个字符序数，返回该字符所在行的长度：

Public Const EM_LINELENGTH = &HC1
Public Function LineLen(txtBox As TextBox, CharPos As Long) As Long
    LineLen = SendMessage( _
            txtBox.hwnd, EM_LINELEENGTH, CharPos, 0&)
End Function

　　 很简单是吗？或者你会说，这也太简单了。OK，我们来看看一些稍微复杂一点的东西。下面介绍的一个函数可以帮你从一个文本框中把一指定行的内容提取出来。这里需要用的消息是EM_GETLINE，行序号放在参数wParam中，在参数lParam中指定一个字符缓冲区用来接受行的内容。

　　 虽然听起来有点简单，实际上问题的麻烦在于在消息中需要为字符缓冲区指定一个最大字符数，把它放在指定缓冲区的前16位中。并且在字符缓冲区中，字符串的形式是不能够直接被VB所能识别的。因为VB所识别的字符串事Unicode编码的，而一般的API函数所返回的都是C语言中的字符数组。这也是在VB中调用API函数会经常碰到的问题。解决的方法是：我们需要使用中间的一个字节数组，然后把这个字节数组转换成一个VB所能识别的字符串。

Public Const EM_GETLINE = &HC4

Public Function GetLine(txtBox As TextBox, LineIndex As Long) As String
    Dim bBuffer() As Byte    '字符数组
    Dim lngLength As Long    '行最大长度
    Dim sRetVal As String    '要返回的字符串
    '检查行号是否合法
    If LineIndex ＞= LineCount(txtBox) Then
        '调用上面提到的LineCount函数
        Exit Function    '错误退出
    End If
    '得到行的长度
    lngLength = LineLen(txtBox, GetCharFromLine(txtBox, LineIndex))
    '检查此行是否有任何的字符
    If lngLength ＜ 1 Then
        Exit Function
    End If
    '重新申明字符数组
    ReDim bBuffer(lngLength)
    '把字符串长度保存在缓冲区的前两个字节中
    bBuffer(0) = lngLength And 255
    bBuffer(1) = lngLength And 256
    '发送消息
    SendMessage txtBox.hWnd, EM_GETLINE, LineIndex, bBuffer(0)
    '最后进行编码转换，并输出字符串
    sRetVal = Left$(StrConv(bBuffer, vbUnicode), lngLength)
    GetLine = sRetVal
End Function

　　 我们还可以做很多类似的事情来扩展VB中标准控件的功能，这儿就不一一列举了。重要的是，你应该知道，VB表面上确实是很简单，很多东西要靠自己不停的发掘才能更好的利用它。下面给出一些其它的消息以供参考：

　　 EM_CANUNDO：判断是否能够对最近一次的修改进行UNDO操作。EM_UNDO：恢复最近一次的修改。

　　 EM_GETMODIFY：判断文本框中的内容是否被更改过了。

　　 EM_SETMODIFY：手工设置修改标志，当文本框的内容被修改过了之后，这个标志被自动的置为ture。

　　 更多的东西，需要你自己的不断的积累，API可谓博大精深，只有使用好它，才能最大限度的发挥VB的威力，也可以为以后转入VC的学习打下坚实的基础。